强烈推荐：Word中写论文时图表使用插入题注和交叉引用

在写论文的时候你还在手动给图表编号吗？如果是，请继续往下看。
写论文时，为了方便修改或增减图表时图表编号可以自动更新，通常可以使用word中强大的 “插入题注” + “交叉引用” 的功能。

在图表下插入题注很简单，不会的可以搜索一下。

但是，Word在插入题注上从03一直到word360一直没有针对中国用户优化，会出现以下问题：

插入题注的标签与编号间有一个空格，当标签是中文时需要用户手动删除
编号后面竟然不插入空格！

当上述两条加到一起时，我插入标签为 “表格”，名称为 “12月的消费清单” 的题注就呈现下面的样子：

表格 112月的消费清单（正确的显示应为：表格1 12月的消费清单）

打印出来就这样，到底是表格1，还是表格11，表格112呢？这时就需要用户前删空格，后添空格，非常繁琐。如果图表过多，手动一个个调仍旧非常繁琐。

为了插入题注时自动删除标签与编号前的空格，编号后添加空格，使用了 ”Endlesswx“的方法，如下所述。

1.插入题注

1.1程序功能

该程序是调用系统的“插入题注对话框”，以前怎么插题注现在还怎么用，零学习成本与多余步骤
中文与编号间自动删除空格，英文与编号间自动保留空格
编号数字与题注内容间添加一个空格，予以区分
程序还支持插入时不填内容、在文档中输好的内容前插入等等，自行体验吧。

1.2使用方法

第一步：录制一个宏（主要为了创建NewMacros模块，以前录制过的请跳过此步），开启录制后可以什么都不干，然后停止录制，记住宏名，默认为“宏1”。

不同版本word的录制宏的方法不一样，以下为word360的方法：

单击“视图”>“宏”>“录制宏”。
键入宏的名称。
若要在创建的所有新文档中使用此宏，请确保“将宏保存在”框中显示了“所有文档 (Normal.dotm)”。
现在，便可以开始录制步骤了。随便点击一下
停止录制，请单击“视图”>“宏”>“停止录制”。

第二步：修改宏代码

查看刚创建的“宏1”

点击“宏1”，再点击右侧编辑，将打开编辑页面，将以下程序代码覆盖粘贴到代码框，结果如下图：

程序代码：

Sub InsertCaption() '修改系统插入“题注”命令
'功能：自动删除标签与编号间的空格（英文除外），并在题注数字后添加一个空格；适用于：Word 2003 - 2013，不兼容WPS文字！
'真正从原理上协同系统插入题注，无任何前提条件；用户照常插入题注即可，甚至感觉不到程序的存在！
'Endlesswx于2015年8月4日
'另,如果插入的始终未域代码而不是数字，非程序问题，Alt+F9一次即可
Dim Lab As String, startPt As Long, endPt As Long, myrang As Range
'On Error Resume Next '发生错误时让程序继续执行下一句代码
' Application.ScreenUpdating = False '关闭屏幕更新，2013在此处关闭更新会导致输入框灰色不可选，故修正在调出对话框之后
startPt = Selection.Start 'startPt标注起始点
'***将if条件隐藏隐藏即可实现----手动替换题注空格***
If Application.Dialogs(357).Show = -1 Then '插入“题注”对话框秀出来,如果按确定结束时执行以下程序，避免按取消后的空格,357也可换成wdDialogInsertCaption
Application.ScreenUpdating = False '关闭屏幕更新
Lab = Dialogs(357).label
endPt = Selection.Start 'endPt标记插入的题注部分终点
Selection.Start = startPt '选定插入的整个题注
'删除标签与编号间的空格（英文后的保留）
With Selection.Find
.Text = Lab & " "
.Forward = True 'False=向上查找,(True=向下查找)
.MatchWildcards = False '不使用通配符
If Lab Like "*[0-9a-zA-Z.]" Then '此处判断标签的最后一个字符是否为英文或数字，是则不删除空格
Else
.Replacement.Text = Lab
.Execute Replace:=wdReplaceOne '替换找到的第一个，此处用作删除空格
endPt = endPt - 1 '删除空格后，末位减1
Selection.End = endPt
End If
End With
'在题注数字后添加一个空格
Selection.Fields.ToggleShowCodes '切换域代码，这样才能用^d查找域
With Selection.Find
.Text = "^d"
.Replacement.Text = "^& "
.Forward = False 'False=向上查找,(True=向下查找)
.MatchWildcards = False '不使用通配符
.Execute Replace:=wdReplaceOne '替换找到的第一个，此处用作添加空格
End With
'选定整个插入的题注内容，将域代码切换回来
endPt = endPt + 1 '增加空格后，末位加1
With Selection
.Start = startPt
.End = endPt
.Fields.ToggleShowCodes '切换域代码（切换回来）
End With
'将光标定位至题注所在段尾处
' Selection.MoveRight Unit:=wdCharacter, Count:=1 '此句光标返回插入题注前的原始位置，对于已经输好标题的情况并不合适
'选择段尾回车符
With Selection.Find
.Text = "^13"
.Forward = True 'False=向上查找,(True=向下查找)
.MatchWildcards = False '不使用通配符
.Wrap = wdFindContinue '继续查找
.Execute
End With
Selection.MoveLeft Unit:=wdCharacter, Count:=1 '定位到段尾回车前
End If
Application.ScreenUpdating = True '恢复屏幕更新
End Sub

插入题注的样式如下: