11.锚杆支护开挖(Excavate with Cable Support)
创建一个名为 “cable_support.3ddat” 的新数据文件。 仍要将模型运行到初始平衡状态。 首先，restore tun_c.3dsav 恢复模型状态，然后重置(reset)位移，问题时间和历史记录。 接下来，指定隧道顶部的监测点以记录楔块的垂直位移，与之前无支护开挖的示例完全相同。
;--- File to simulate excavation with cable support ---
restore tun_c.3dsav
reset disp time hist
his ncycle 10
hide
seek range xr -0.3 .46 zr 3.8 4.5 yr -1.0 1.0
group block "wedge"
hist zdis 0 0 3.9
hist label 1 'Vertical Displacement'
seek锚杆结构单元代表完全灌浆的锚杆螺栓，有关的详细信息，请参见 Theory and Background (3DEC Manual) 中的第4节。 锚杆结构单元的属性如下：
截面积为0.0005 m2（area），杨氏模量为100 GPa(emod)，拉伸屈服强度（yield）为0.55 MN，水泥浆的粘结刚度等于150 GN/m/m（kbond），水泥浆的粘结强度等于0.8 MN/m（sbond）。 property ID在特定属性之前分配（ID = 8）。
; start with high SBOND
struct prop 8 area 5e-4 e 100000 yield 0.55 kbond 15e4 sbond 0.8隧道是分阶段开挖的，每个阶段之后，在工作面的后面 1m 处安装5个锚杆支护。 每次开挖后，均使用 solve 命令求解。 请注意，在这种情况下，不平衡力比(ratio)设置为 1e-8。这是因为，如果使用默认比率（1e-5），仍然会观察到运动。 当使用solve 命令指定比率时，所有后续solve 命令将使用相同比率。
请注意，这里我们使用remove命令而不是delete命令，因为我们希望能够绘制出挖掘的区域（请参见下文）。 struct cable命令定义每个单元的端点，并分配结构属性。 附加的seg关键字用于指定每根锚杆分为多少段。 在这种情况下，每条锚杆分为四段，总共有15个锚杆支护。 第一阶段的挖掘和锚杆安装如下：
; delete interior blocks in stages while installing support
; --- install cable elements ---
remove range group tunnel y @stage0,@stage1
solve ratio 1e-8
; support elements at y = -6 (stage 1)
struct cable -8 -6 -2 -4.05 -6 -2 prop 8 seg 4
struct cable -6.8 -6 6.8 -2.85 -6 2.85 prop 8 seg 4
struct cable 0.1 -6 4.1 0.1 -6 8 prop 8 seg 4
struct cable 6.8 -6 6.8 2.85 -6 2.85 prop 8 seg 4
struct cable 8 -6 -2 4.05 -6 -2 prop 8 seg 4
save cable1执行数据文件。 要绘制锚杆，请创建一个名为 Support 的新绘图窗口。 添加 Blocks → Group。 取消选中 Transparency 复选框，然后取消选中 Colors 属性上的 Defualt。 现在添加一个 Block 图项显示出块体。
在 Attributes 中，单击 Excavations 复选框，这将仅绘制出挖掘的块体。 同样，取消选中 Fill 旁边的复选框，以便仅显示隧道开挖部分的线框图。 现在，再次单击 List 选项卡。 选择 Cables → Contours → Axial Force。 旋转并放大，绘图应如下所示：
可以看到锚杆中的轴向力当前为0。这是因为已安装锚杆，但未执行任何计算循环。 现在通过以下命令挖掘并支护下一阶段。
remove range group tunnel y @stage1,@stage2
solve
; support elements at y = -1 (stage 2)
struct cable -8 -1 -2 -4.05 -1 -2 prop 8 seg 4
struct cable -6.8 -1 6.8 -2.85 -1 2.85 prop 8 seg 4
struct cable 0.1 -1 4.1 0.1 -1 8 prop 8 seg 4
struct cable 6.8 -1 6.8 2.85 -1 2.85 prop 8 seg 4
struct cable 8 -1 -2 4.05 -1 -2 prop 8 seg 4
save cable2执行文件后，Support 视图窗口应该会如下所示：
可以看到，锚杆中正在形成力。 如下命令执行挖掘的最后两个阶段。
remove range group tunnel y @stage2,@stage3
solve
; support elements at y = +4 (stage 3)
struct cable -8 4 -2 -4.05 4 -2 prop 8 seg 4
struct cable -6.8 4 6.8 -2.85 4 2.85 prop 8 seg 4
struct cable 8 4 -2 4.05 4 -2 prop 8 seg 4
struct cable 6.8 4 6.8 2.85 4 2.85 prop 8 seg 4
struct cable 0.1 4 4.1 0.1 4 8 prop 8 seg 4
save cable3
;
remove range group tunnel y @stage3,@stage4
solve
save tun_cable执行文件后，Support 视图窗口应该会如下所示：
可以看到锚杆上有很大的力在支撑楔块。单击 Hist 绘图窗口，会看到楔块的位移监测记录，图中显示楔块已稳定。
12.衬砌支护(Liner Support)
创建一个名为 “liner_support.3ddat” 的新数据文件。 restore tun_c.3dsav还原初始保存状态。 通过使用 config 命令和后面的 liner 关键字来指定其他计算模式。 通过使用表面区域范围，可以最轻松地实现衬砌。 表面区域范围代表两个区域的交点。 以下命令在岩石（区域0）和要开挖的隧道（区域5）的交点处创建表面区域。
;--- File to simulate excavation with cable support ---
rest tun_c.3dsav
reset disp time hist
his ncycle 10
config liner
mark sregion 2 range rint 0 5与前面的示例类似，监测记录隧道顶部相同的点。
hide
seek range xr -0.3 .46 zr 3.8 4.5 yr -1.0 1.0
group block "wedge"
hist zdis 0 0 3.9
hist label 1 'Vertical Displacement'
seek衬砌的材料属性如下：
衬砌-岩石接触属性如下：
衬砌-岩石接触属性设置了很高的强度和刚度，以确保不会发生相对运动或打滑。 衬砌本身被赋予混凝土的真实属性。
struc prop 1 fric 60 coh 50e3 kn 100e3 ks 100e3 &
nu 0.15 thick 0.2 e 15e3 tens 25e3接下来，我们可以开始分阶段的挖掘，并在每次挖掘之后安装衬砌。 开挖和支撑第一阶段的命令如下。
; --- insert liner in stages ---
remove range group 'tunnel' y @stage0,@stage1
solve ratio 1e-8
struct liner face_gen prop 1 range sreg 2 y @stage0,@stage1
save liner1执行数据文件。 单击 Support 视图窗口，隐藏 Cable axial force 图项(点击眼睛图标按钮隐藏)。 在控制面板 List 选项卡下，选择 Liners → Contours → Displacement。 该图应如下所示：
与锚杆一样，由于衬砌已安装但尚未执行任何计算循环，因此衬砌尚未显示位移。如下命令执行下一个开挖阶段。
remove range group 'tunnel' y @stage1,@stage2
solve
struct liner face_gen prop 1 range sreg 2 y @stage1,@stage2
save liner2执行数据文件。 单击 Support 视图窗口，将看到衬砌出现一些位移：
开挖剩下的阶段：
remove range group 'tunnel' y @stage2,@stage3
solve
struct liner face_gen prop 1 range sreg 2 y @stage2,@stage3
save liner3
remove range group 'tunnel' y @stage3,@stage4
solve
struct liner face_gen prop 1 range sreg 2 y @stage3,@stage4
save tun_liner执行数据文件。 单击 Support 视图窗口，最后一阶段如下图所示：
请注意，由于模型已经达到平衡，因此衬砌安装的最后部分无效，但是，如果计划进一步进行挖掘或模型扰动，则安装此衬砌将是必要的步骤。Hist 视图窗口将显示楔块的垂直位移。
该图表明衬砌已稳定了楔块。
可以看到在刚性衬砌中的最大位移约为1毫米，而在最后的部分中没有位移。
13.完结撒花(Conclusion)
本教程到此结束，您可以通过单击 File → Save Project 来保存项目。 保存项目后，可以通过选择 File → Close Project 退出项目。