接上一节：3DEC动力分析示例(1):阻尼、网格、自由场边界等的介绍

5. 动力荷载的输入方式

在3DEC中，动力输入可以采用两种方法：输入预处理过的速度时程或者输入应力时程。

对前者，如果是加速度时间序列，则需要进行数值积分转化为速度序列，如果是位移序列，则需要数值微分转化为速度序列。下面为几种具体的输入形式：

（1）由正弦和余弦函数定义的简谐波函数；

（2） 由 TABLE 命令定义的数据表；

（3） 由 BOUNDARY 命令输入的速度（加速度或应力）历时曲线；

（4） 用户自编的FISH函数。

3DEC中模型边界默认为自由边界（反射边界），应力波在这些位置会发生反射，将应力波反射回模型内部，而不是能量吸收边界（无反射边界），因此直接输入速度波，模型范围需要足够大，使得关心区域远离边界才可能得到较为理想结果。为了避免这种情况，可以将速度记录转化为应力时程，并在边界上施加无反射（黏性）边界条件。

一般动力荷载垂直施加于模型底部（或顶部），而且由于模型底部（或顶部）采用的是粘滞边界，不能直接输入速度时程，因此将采用输入应力时程的方式来输入动力荷载。将速度时程转化成应力时程，其计算公式如下：

式中，σn 和 σs 分别为施加的法向、切向应力；Vn 和 Vs 分别为施加的法向速度与切向速度；Cp 和 Cs 分别为纵波波速和横波波速；ρ 为介质密度。

注意，公式中施加的应力均为2 倍应力波振面上的应力，这是由于施加动荷载的边界上同时施加了无反射边界，需要克服黏滞边界效应。

此时如果在黏滞边界上施加的不是应力时间序列，而是速度时间序列，则不能乘倍数2。

即使施加的是应力时间序列，在边界上监控质点的速度响应与原始输入速度也不相同，这是因为以上公式是基于一维应力波传播的近似公式，而真实的应力波传播要复杂得多。同时，作为输入的时间序列必须进行基线修正，以保证岩土介质的变形破坏为动荷载引起。

上式中纵波波速和横波波速Cp 、Cs 可由下式确定：

式中，K 为岩体体积模量；G 为岩体剪切模量；ρ 为岩体密度。

6. 大坝的地震响应实例分析

下图是简单混凝土大坝的模型，顶部是自由边界，底部是粘滞边界（无反射边界）。

该模型首先在重力作用下达到静态平衡，以平衡体力和边界力。 这必须在施加自由场边界之前完成。命令如下：

new
; -------------------------------------------------------------------
;
; example of dynamic free-field analysis of dam
;  impulse stress wave applied at base, free top
;
; -------------------------------------------------------------------
;
config dyn lh ;开启动力分析模式，转换坐标轴为左手系
;注意3DEC默认都是右手系，这里转换成了左手系，且 Y 轴必须向上，不清楚的可以看上一节的注意事项
title
Dynamic Analysis of a Dam
;
;创建块体并使用节理切割
po reg -100 100  -100 0  -100 100
plot create plot Blocks
plot block
plot reset
plot set dip 125 dd 60
jset  dip 0 dd 0 or 0 -30 0
hide range y -100 -30
jset  dip 45 dd 0   or 0 0 -50
jset  dip 45 dd 180 or 0 0  50
hide  range z -100 -50
hide  range z  50 100
jset  dip 90 dd 90  or -12 0 0
del range x -100 -12  y -30 0 z -50 50
jset  dip 51 dd 90  or -12 0 0
del range x 12 100  y -30 0  z -50 50
change mat 2
find
hide range bmat 2
join
jset  dip 30 dd 270 or 30 -30 0  sp 50 n 5
find
gen ed 26 

;
; E = 50000 MPa, v=0.25
; dens = 2500 kg/m3
; cp = 4899 m/s
; cs = 2828 m/s
;赋予块体及节理的属性
prop  mat 1 dens 0.0025  bulk 33333 shear 20000
prop jmat 1 jkn 10000 jks 4000 jcoh 1e10 jtens 1e10
prop  mat 2 dens 0.0025  bulk 20000 shear 12000
prop jmat 2 jkn 10000 jks 4000 jcoh 1e10 jtens 1e10

;施加边界条件
;底部竖向固定
bou yvel 0 range y -101 -99
;四周固定边界
bou xvel 0 range x -101 -99
bou xv 0 range x 99 101
bou zv 0 range z -101 -99
bou zv 0 range z 99 101
;施加竖向的自重应力的应力梯度
insitu stress 0 0 0 0 0 0  ygrad 0.00125 0.0025 0.00125 0 0 0
grav 0 -10 0

damp auto
cycle 2000
;
damp 0 0 mass
reset time hist disp
;记录变量
hist unbal
hist xvel 0 0 0
hist xvel 0 -100 0
hist xvel -40 -28 -20
hist label 2 'X velocity at crest'
hist label 3 'X velocity at base'
save ff1.3dsav

如果四周仅使用粘性边界运行模型看看效果。 这里切向脉冲应力函数施加于模型的底部。 在该模型中，边界太近了，从下图中可以看出，底部的x速度放大了，坝顶的运动变形了。

四周施加粘性边界的模型命令：

;run with viscous boundaries
;
res ff1.3dsav
;
; viscous boundaries only
;更改四周边界条件为粘性边界
boun xvisc range x -101 -99
boun xvisc range x 99 101
boun zvisc range z -101 -99
boun zvisc range z 99 101
;底部施加切向脉冲应力荷载
bound str 0 0 0 2.0 0 0 hist imp 5 1000 range y -101 -99
;底部三个方向均施加粘性边界
bound xvisc yvisc zvisc range y -101 -99
bound mat 1
cy ti 0.4
save ff2.3dsav
plot create plot Hist
plot hist 2 3 linestyle style dot xaxis label 'Cycles' yaxis label 'Velocity'

接下来，使用自由场边界重新运行模型。 free field命令在模型的边界处创建新的块体，并自动对其进行分区。 底部施加切向脉冲应力荷载。下图显示了底部和坝顶的x速度历史记录。 在这种情况下，在坝顶处基波没有放大或失真。

四周施加自由场边界的命令如下：

;
; run with Free Field Boundary
;
res  ff1.3dsav
;
; --- create FF ---
;
;施加自由场边界
ffield  apply gap 10 thick 10
;底部施加切向脉冲应力荷载且底部三个方向均施加粘性边界
bound str 0 0 0 2.0 0 0 hist imp 5 1000 range y -101 -99  
bound xvisc yvisc zvisc range y -101 -99  
bound mat 1
cy ti 0.4
save ff3.3dsav
plot create plot Hist
plot hist 2 3 linestyle style dot xaxis label 'Cycles' yaxis label 'Velocity'
ret

后面将写一些UDEC关于边坡动力加载、地震加载等的实例，与3DEC的差不多，可以互相对照着看。